emit_x64_floating_point: Optimize 32-bit EmitFPRSqrtEstimate

tests/CMakeLists.txt

@@ -19,6 +19,13 @@ add_executable(dynarmic_tests
     rand_int.h
 )
 
+if (NOT MSVC)
+    target_sources(dynarmic_tests PRIVATE
+        rsqrt_test.cpp
+        rsqrt_test_fn.s
+    )
+endif()
+
 if (DYNARMIC_TESTS_USE_UNICORN)
     target_sources(dynarmic_tests PRIVATE
         A32/fuzz_arm.cpp
@@ -47,7 +54,7 @@ create_target_directory_groups(dynarmic_print_info)
 target_link_libraries(dynarmic_tests PRIVATE dynarmic boost catch fmt mp xbyak)
 target_include_directories(dynarmic_tests PRIVATE . ../src)
 target_compile_options(dynarmic_tests PRIVATE ${DYNARMIC_CXX_FLAGS})
-target_compile_definitions(dynarmic_tests PRIVATE FMT_USE_USER_DEFINED_LITERALS=0)
+target_compile_definitions(dynarmic_tests PRIVATE FMT_USE_USER_DEFINED_LITERALS=0 CATCH_CONFIG_ENABLE_BENCHMARKING=1)
 
 target_link_libraries(dynarmic_print_info PRIVATE dynarmic boost catch fmt mp)
 target_include_directories(dynarmic_print_info PRIVATE . ../src)

tests/rsqrt_test.cpp

@@ -0,0 +1,148 @@
+/* This file is part of the dynarmic project.
+ * Copyright (c) 2021 MerryMage
+ * SPDX-License-Identifier: 0BSD
+ */
+
+#include <catch.hpp>
+#include <fmt/printf.h>
+
+#include "common/common_types.h"
+#include "common/fp/fpcr.h"
+#include "common/fp/fpsr.h"
+#include "common/fp/op/FPRSqrtEstimate.h"
+
+extern "C" u32 rsqrt_inaccurate(u32);
+extern "C" u32 rsqrt_full(u32);
+extern "C" u32 rsqrt_full_gpr(u32);
+extern "C" u32 rsqrt_full_nb(u32);
+extern "C" u32 rsqrt_full_nb2(u32);
+extern "C" u32 rsqrt_full_nb_gpr(u32);
+extern "C" u32 rsqrt_newton(u32);
+extern "C" u32 rsqrt_hack(u32);
+
+using namespace Dynarmic;
+
+extern "C" u32 rsqrt_fallback(u32 value) {
+    FP::FPCR fpcr;
+    FP::FPSR fpsr;
+    return FP::FPRSqrtEstimate(value, fpcr, fpsr);
+}
+
+void Test(u32 value) {
+    FP::FPCR fpcr;
+    FP::FPSR fpsr;
+
+    const u32 expect = FP::FPRSqrtEstimate(value, fpcr, fpsr);
+    const u32 full = rsqrt_full(value);
+    const u32 full_gpr = rsqrt_full_gpr(value);
+    const u32 newton = rsqrt_newton(value);
+    const u32 hack = rsqrt_hack(value);
+
+    if (expect != full || expect != full_gpr || expect != newton || expect != hack) {
+        fmt::print("{:08x} = {:08x} : {:08x} : {:08x} : {:08x} : {:08x}\n", value, expect, full, full_gpr, newton, hack);
+
+        REQUIRE(expect == full);
+        REQUIRE(expect == full_gpr);
+        REQUIRE(expect == newton);
+        REQUIRE(expect == hack);
+    }
+}
+
+TEST_CASE("RSqrt Tests", "[fp][.]") {
+    Test(0x00000000);
+    Test(0x80000000);
+    Test(0x7f8b7201);
+    Test(0x7f800000);
+    Test(0x7fc00000);
+    Test(0xff800000);
+    Test(0xffc00000);
+    Test(0xff800001);
+
+    for (u64 i = 0; i < 0x1'0000'0000; i++) {
+        const u32 value = static_cast<u32>(i);
+        Test(value);
+    }
+}
+
+TEST_CASE("Benchmark RSqrt", "[fp][.]") {
+    BENCHMARK("Inaccurate") {
+        u64 total = 0;
+        for (u64 i = 0; i < 0x1'0000'0000; i += 0x1234) {
+            const u32 value = static_cast<u32>(i);
+            total += rsqrt_inaccurate(value);
+        }
+        return total;
+    };
+
+    BENCHMARK("Full divss") {
+        u64 total = 0;
+        for (u64 i = 0; i < 0x1'0000'0000; i += 0x1234) {
+            const u32 value = static_cast<u32>(i);
+            total += rsqrt_full(value);
+        }
+        return total;
+    };
+
+    BENCHMARK("Full divss (GPR)") {
+        u64 total = 0;
+        for (u64 i = 0; i < 0x1'0000'0000; i += 0x1234) {
+            const u32 value = static_cast<u32>(i);
+            total += rsqrt_full_gpr(value);
+        }
+        return total;
+    };
+
+    BENCHMARK("Full divss (NB)") {
+        u64 total = 0;
+        for (u64 i = 0; i < 0x1'0000'0000; i += 0x1234) {
+            const u32 value = static_cast<u32>(i);
+            total += rsqrt_full_nb(value);
+        }
+        return total;
+    };
+
+    BENCHMARK("Full divss (NB2)") {
+        u64 total = 0;
+        for (u64 i = 0; i < 0x1'0000'0000; i += 0x1234) {
+            const u32 value = static_cast<u32>(i);
+            total += rsqrt_full_nb2(value);
+        }
+        return total;
+    };
+
+    BENCHMARK("Full divss (NB + GPR)") {
+        u64 total = 0;
+        for (u64 i = 0; i < 0x1'0000'0000; i += 0x1234) {
+            const u32 value = static_cast<u32>(i);
+            total += rsqrt_full_nb_gpr(value);
+        }
+        return total;
+    };
+
+    BENCHMARK("One Newton iteration") {
+        u64 total = 0;
+        for (u64 i = 0; i < 0x1'0000'0000; i += 0x1234) {
+            const u32 value = static_cast<u32>(i);
+            total += rsqrt_newton(value);
+        }
+        return total;
+    };
+
+    BENCHMARK("Ugly Hack") {
+        u64 total = 0;
+        for (u64 i = 0; i < 0x1'0000'0000; i += 0x1234) {
+            const u32 value = static_cast<u32>(i);
+            total += rsqrt_hack(value);
+        }
+        return total;
+    };
+
+    BENCHMARK("Softfloat") {
+        u64 total = 0;
+        for (u64 i = 0; i < 0x1'0000'0000; i += 0x1234) {
+            const u32 value = static_cast<u32>(i);
+            total += rsqrt_fallback(value);
+        }
+        return total;
+    };
+}

tests/rsqrt_test_fn.s

@@ -0,0 +1,303 @@
+.global _rsqrt_inaccurate
+.global rsqrt_inaccurate
+.global _rsqrt_full
+.global rsqrt_full
+.global _rsqrt_full_gpr
+.global rsqrt_full_gpr
+.global _rsqrt_full_nb
+.global rsqrt_full_nb
+.global _rsqrt_full_nb2
+.global rsqrt_full_nb2
+.global _rsqrt_full_nb_gpr
+.global rsqrt_full_nb_gpr
+.global _rsqrt_newton
+.global rsqrt_newton
+.global _rsqrt_hack
+.global rsqrt_hack
+.global _rsqrt_fallback
+
+.text
+.intel_syntax
+
+.align 16
+min_pos_denorm:
+.long 0x00800000,0,0,0
+penultimate_bit:
+.long 0x00008000,0,0,0
+ultimate_bit:
+.long 0x00004000,0,0,0
+top_mask:
+.long 0xFFFF8000,0,0,0
+one:
+.long 0x3f800000,0,0,0
+half:
+.long 0x3f000000,0,0,0
+one_point_five:
+.long 0x3fc00000,0,0,0
+magic1:
+.long 0x60000000,0,0,0
+magic2:
+.long 0x3c000000,0,0,0
+magic3:
+.long 0x000047ff,0,0,0
+
+_rsqrt_inaccurate:
+rsqrt_inaccurate:
+    movd xmm0, edi
+
+    rsqrtss xmm0, xmm0
+
+    movd eax, xmm0
+    ret
+
+_rsqrt_full:
+rsqrt_full:
+    movd xmm0, edi
+
+    pand xmm0, [rip + top_mask]
+    por xmm0, [rip + penultimate_bit]
+
+    vcmpngt_uqss xmm1, xmm0, [rip + min_pos_denorm]
+    ptest xmm1, xmm1
+    jnz rsqrt_full_bad
+
+    sqrtss xmm0, xmm0
+
+    movd xmm1, [rip + one]
+    divss xmm1, xmm0
+
+    paddd xmm1, [rip + ultimate_bit]
+    pand xmm1, [rip + top_mask]
+
+    movd eax, xmm1
+    ret
+
+_rsqrt_full_gpr:
+rsqrt_full_gpr:
+    movd eax, xmm0 # Emulate regalloc mov
+
+    mov eax, edi
+    and eax, 0xFFFF8000
+    or eax, 0x00008000
+
+    movd xmm0, eax
+    vcmpngt_uqss xmm1, xmm0, [rip + min_pos_denorm]
+    ptest xmm1, xmm1
+    jnz rsqrt_full_bad
+
+    sqrtss xmm0, xmm0
+
+    movd xmm1, [rip + one]
+    divss xmm1, xmm0
+    movd eax, xmm1
+
+    add eax, 0x00004000
+    and eax, 0xffff8000
+
+    movd xmm0, eax # Emulate regalloc mov
+    ret
+
+_rsqrt_full_nb2:
+rsqrt_full_nb2:
+    movd xmm0, edi
+
+    pand xmm0, [rip + top_mask]
+    por xmm0, [rip + penultimate_bit]
+
+    ucomiss xmm0, [rip + min_pos_denorm]
+    jna rsqrt_full_bad_new1
+
+    sqrtss xmm0, xmm0
+
+    movd xmm1, [rip + one]
+    divss xmm1, xmm0
+
+    paddd xmm1, [rip + ultimate_bit]
+    pand xmm1, [rip + top_mask]
+
+    movd eax, xmm1
+    ret
+
+_rsqrt_full_nb:
+rsqrt_full_nb:
+    movd xmm0, edi
+
+    pand xmm0, [rip + top_mask]
+    por xmm0, [rip + penultimate_bit]
+
+    vcmpngt_uqss xmm1, xmm0, [rip + min_pos_denorm]
+    ptest xmm1, xmm1
+    jnz rsqrt_full_bad_new1
+
+    sqrtss xmm0, xmm0
+
+    movd xmm1, [rip + one]
+    divss xmm1, xmm0
+
+    paddd xmm1, [rip + ultimate_bit]
+    pand xmm1, [rip + top_mask]
+
+    movd eax, xmm1
+    ret
+
+rsqrt_full_bad_new1:
+    cmp edi, 0x00800000
+    jb rsqrt_full_bad_new_fallback1
+
+    movd xmm0, edi
+    rsqrtss xmm1, xmm0
+
+    ucomiss xmm1, xmm1
+    jp rsqrt_full_bad_new1_nan
+
+    movd eax, xmm1
+    ret
+
+rsqrt_full_bad_new_fallback1:
+    call _rsqrt_fallback
+    ret
+
+rsqrt_full_bad_new1_nan:
+    ucomiss xmm0, xmm0
+    jp rsqrt_full_bad_new1_nan_ret
+
+    mov eax, 0x7FC00000
+    ret
+
+rsqrt_full_bad_new1_nan_ret:
+    ret
+
+_rsqrt_full_nb_gpr:
+rsqrt_full_nb_gpr:
+    movd eax, xmm0 # Emulate regalloc mov
+
+    mov eax, edi
+    and eax, 0xFFFF8000
+    or eax, 0x00008000
+
+    movd xmm0, eax
+    vcmpngt_uqss xmm1, xmm0, [rip + min_pos_denorm]
+    ptest xmm1, xmm1
+    jnz rsqrt_full_bad_new2
+
+    sqrtss xmm0, xmm0
+
+    movd xmm1, [rip + one]
+    divss xmm1, xmm0
+    movd eax, xmm1
+
+    add eax, 0x00004000
+    and eax, 0xffff8000
+
+    movd xmm0, eax # Emulate regalloc mov
+    ret
+
+rsqrt_full_bad_new2:
+    cmp edi, 0x00800000
+    jb rsqrt_full_bad_new_fallback2
+
+    movd xmm0, edi
+    rsqrtss xmm1, xmm0
+
+    test edi, edi
+    js rsqrt_full_bad_new2_nan
+
+    movd eax, xmm1
+    ret
+
+rsqrt_full_bad_new_fallback2:
+    call _rsqrt_fallback
+    ret
+
+rsqrt_full_bad_new2_nan:
+    mov eax, 0x7FC00000
+    ret
+
+rsqrt_full_bad:
+    xorps xmm1, xmm1
+    movd xmm0, edi
+    ucomiss xmm0, xmm1
+    jp rsqrt_full_nan
+    je rsqrt_full_zero
+    jc rsqrt_full_neg
+
+    cmp edi, 0x7F800000
+    je rsqrt_full_inf
+
+    # TODO: Full Denormal Implementation
+    call _rsqrt_fallback
+    ret
+
+rsqrt_full_neg:
+    mov eax, 0x7FC00000
+    ret
+
+rsqrt_full_inf:
+    xor eax, eax
+    ret
+
+rsqrt_full_nan:
+    mov eax, edi
+    or eax, 0x00400000
+    ret
+
+rsqrt_full_zero:
+    mov eax, edi
+    or eax, 0x7F800000
+    ret
+
+_rsqrt_newton:
+rsqrt_newton:
+    movd xmm0, edi
+
+    pand xmm0, [rip + top_mask]
+    por xmm0, [rip + penultimate_bit]
+
+    vcmpngt_uqss xmm1, xmm0, [rip + min_pos_denorm]
+    ptest xmm1, xmm1
+    jnz rsqrt_full_bad
+
+    rsqrtps xmm1, xmm0
+    mulss xmm0, [rip + half]
+    vmulss xmm2, xmm1, xmm1
+    mulss xmm2, xmm0
+    movaps xmm0, [rip + one_point_five]
+    subss xmm0, xmm2
+    mulss xmm0, xmm1
+
+    paddd xmm0, [rip + ultimate_bit]
+    pand xmm0, [rip + top_mask]
+
+    movd eax, xmm0
+    ret
+
+_rsqrt_hack:
+rsqrt_hack:
+    movd xmm9, edi
+
+    vpand xmm0, xmm9, [rip + top_mask]
+    por xmm0, [rip + penultimate_bit]
+
+    # detect NaNs, negatives, zeros, denormals and infinities
+    vcmpngt_uqss xmm1, xmm0, [rip + min_pos_denorm]
+    ptest xmm1, xmm1
+    jnz rsqrt_full_bad
+
+    # calculate x64 estimate
+    rsqrtps xmm0, xmm0
+
+    # calculate correction factor
+    vpslld xmm1, xmm9, 8
+    vpsrad xmm2, xmm1, 31
+    paddd xmm1, [rip + magic1]
+    pcmpgtd xmm1, [rip + magic2]
+    pxor xmm1, xmm2
+    movaps xmm2, [rip + magic3]
+    psubd xmm2, xmm1
+
+    # correct x64 estimate
+    paddd xmm0, xmm2
+    pand xmm0, [rip + top_mask]
+
+    movd eax, xmm0
+    ret