CMakeLists: Support multi-architecture builds

CMakeModules/DetectArchitecture.cmake

@@ -1,5 +1,11 @@
 include(CheckSymbolExists)
 
+if (CMAKE_OSX_ARCHITECTURES)
+    set(DYNARMIC_MULTIARCH_BUILD 1)
+    set(ARCHITECTURE "${CMAKE_OSX_ARCHITECTURES}")
+    return()
+endif()
+
 function(detect_architecture symbol arch)
     if (NOT DEFINED ARCHITECTURE)
         set(CMAKE_REQUIRED_QUIET YES)

CMakeModules/TargetArchitectureSpecificSources.cmake

@@ -0,0 +1,26 @@
+function(target_architecture_specific_sources project arch)
+    if (NOT DYNARMIC_MULTIARCH_BUILD)
+        target_sources("${project}" PRIVATE ${ARGN})
+        return()
+    endif()
+
+    foreach(input_file IN LISTS ARGN)
+        if(input_file MATCHES ".cpp$")
+            if(NOT IS_ABSOLUTE ${input_file})
+                set(input_file "${CMAKE_CURRENT_SOURCE_DIR}/${input_file}")
+            endif()
+
+            set(output_file "${CMAKE_CURRENT_BINARY_DIR}/arch_gen/${input_file}")
+            add_custom_command(
+                OUTPUT "${output_file}"
+                COMMAND ${CMAKE_COMMAND} "-Darch=${arch}"
+                                         "-Dinput_file=${input_file}"
+                                         "-Doutput_file=${output_file}"
+                                         -P "${CMAKE_CURRENT_FUNCTION_LIST_DIR}/impl/TargetArchitectureSpecificSourcesWrapFile.cmake"
+                DEPENDS "${input_file}"
+                VERBATIM
+            )
+            target_sources(${project} PRIVATE "${output_file}")
+        endif()
+    endforeach()
+endfunction()

CMakeModules/impl/TargetArchitectureSpecificSourcesWrapFile.cmake

@@ -0,0 +1,3 @@
+string(TOUPPER "${arch}" arch)
+file(READ "${input_file}" f_contents)
+file(WRITE "${output_file}" "#include <mcl/macro/architecture.hpp>\n#if defined(MCL_ARCHITECTURE_${arch})\n${f_contents}\n#endif\n")